*****************************************************
*  TP Cast3M : modèle 2D de la pièce
*                                         H. Oudin           
OPTION DIME 2 ELEM QUA4 MODE PLAN CONT;
*données en mm et N  (MPa)
       lx = 300. ; ep = 5.; b2 = 10.;
       yEp = 210000.; nup = 0.3 ; rhop = 7800.e-9; 
       fapp = 300. ; fnoeu = fapp*4.;
* maillage nb d'éléments
       N1 = 10 ; N2=4 ;
       
*  solution analytique
momA = fapp*80; b = 2.*b2; IZ1 = ep*(b**3)/12.;
coef = (momA*lx*lx)/(6*yEp*IZ1);
LXA = PROG 0. PAS 10 lx;
Npts = DIME LXA ; L1 = PROG Npts*1;
Depv = coef*(LXA/lx)*((LXA/lx)*(3*L1-(LXA/lx))-(2*L1));
EVv = EVOL bleu MANU variable LXA Densité Depv;
sigmax = ABS(momA*b/(2*IZ1));
sigxx = sigmax*(L1-(LXA/lx));
EVsig = EVOL bleu MANU variable LXA Densité sigxx;
*****************************************************
*		                        géométrie et maillage
P1 = 0. 0.;
P2 = lx 0.;
D1 = DROIT N1 P1 P2 ;
SUR1 = D1 TRAN N2 (0. 10); SUR2 = D1 TRAN N2 (0. -10);
poutre = SUR1 ET SUR2;                 
P3 = 0. 10;
P4 = 0. -10;
P5 = lx -10.;
D2 =DROI N1 P4 P5;
ELIM poutre (P3 ET P4 ET D2) 0.001;
TRAC poutre TITR 'Maillage de la poutre';
*****************************************************  
* 	Modèle et Caracteristiques mécaniques	
mod1 = MODE poutre mecanique elastique isotrope;
mat1 = MATE mod1 YOUN yEp NU nup RHO rhop DIM3 ep; 
*****************************************************
* 	 conditions aux limites
cl1 = BLOQ DEPL P1; cl2 = BLOQ UY P2;
Clt = cl1 ET cl2;
*****************************************************
*      charge ponctuelle 
cha1 = FORCE FX fnoeu P3; Cha2 =FORCE FX (-1*fnoeu) P4;
Chat =cha1 ET cha2;
VEC1 = VECT chat FX FY vert ;
*****************************************************
* 				Matrice raideur et resolution
rigid1 = RIGI mod1 mat1 ; 
raidt = rigid1 ET clt; 
dep1 = RESO raidt chat;
******************************************************
*                             post-traitement
*  option des isovaleurs et fichier résultats
   OPTI ISOV surf ; 
*                            déformée
def0 = DEFO dep1 poutre 0. vert;
def1 = DEFO dep1 poutre rouge;
TRAC (def0 ET def1) TITRE 'déformée de la structure'; 
depy = EXCO UY dep1;
TITRE 'déplacement Uy en mm le long de L1';
EVOL1 = EVOL CHPO dep1 UY  D1;  DESS (EVv ET EVOL1) MIMA;

*                 contraintes
sigr = SIGM mod1 mat1 dep1; 
*LIST RESUM sigr;
vec1 = 1. 0. ; vec2 = 0. 1.;
sig1 = RTEN sigr mod1 vec1 vec2;
vmis1 = VMIS mod1 sig1;
*List vmis1;
TRAC vmis1 mod1  TITRE 'Von Mises en MPa';

sig1xx = EXCO smxx sig1 ; 
TRAC mod1 sig1xx TITRE 'sigxx ';
eff = CHANGER CHPO mod1 sig1;
Mffz = EXCO smxx  eff;
EVOL1 = EVOL CHPO Mffz D2;  DESS (EVsig ET EVOL1) MIMA;
FIN;